Use Autoconf provided AS_HELP_STRING macro to automatically format and

align strings in the --help output.  Do this through our abstraction layer
to eliminate redundancy and randomness in configure.in.

config/general.m4

-# $PostgreSQL: pgsql/config/general.m4,v 1.9 2006/11/30 22:21:23 tgl Exp $
+# $PostgreSQL: pgsql/config/general.m4,v 1.10 2008/10/29 09:27:24 petere Exp $
 
 # This file defines new macros to process configure command line
 # arguments, to replace the brain-dead AC_ARG_WITH and AC_ARG_ENABLE.
@@ -17,14 +17,19 @@ m4_define([pgac_arg_to_variable],
           [$1[]_[]patsubst($2, -, _)])
 
 
-# PGAC_ARG(TYPE, NAME, HELP-STRING,
+# PGAC_ARG(TYPE, NAME, HELP-STRING-LHS-EXTRA, HELP-STRING-RHS,
 #          [ACTION-IF-YES], [ACTION-IF-NO], [ACTION-IF-ARG],
 #          [ACTION-IF-OMITTED])
-# ----------------------------------------------------------
+# ------------------------------------------------------------
 # This is the base layer. TYPE is either "with" or "enable", depending
-# on what you like. NAME is the rest of the option name, HELP-STRING
-# as usual. ACTION-IF-YES is executed if the option is given without
-# an argument (or "yes", which is the same); similar for ACTION-IF-NO.
+# on what you like.  NAME is the rest of the option name.
+# HELP-STRING-LHS-EXTRA is a string to append to the option name on
+# the left-hand side of the help output, e.g., an argument name.  If
+# set to "-", append nothing, but let the option appear in the
+# negative form (disable/without).  HELP-STRING-RHS is the option
+# description, for the right-hand side of the help output.
+# ACTION-IF-YES is executed if the option is given without an argument
+# (or "yes", which is the same); similar for ACTION-IF-NO.
 
 AC_DEFUN([PGAC_ARG],
 [
@@ -32,37 +37,37 @@ pgac_args="$pgac_args pgac_arg_to_variable([$1],[$2])"
 m4_case([$1],
 
 enable, [
-AC_ARG_ENABLE([$2], [$3], [
+AC_ARG_ENABLE([$2], [AS_HELP_STRING([--]m4_if($3, -, disable, enable)[-$2]m4_if($3, -, , $3), [$4])], [
   case [$]enableval in
     yes)
-      m4_default([$4], :)
+      m4_default([$5], :)
       ;;
     no)
-      m4_default([$5], :)
+      m4_default([$6], :)
       ;;
     *)
-      $6
+      $7
       ;;
   esac
 ],
-[$7])[]dnl AC_ARG_ENABLE
+[$8])[]dnl AC_ARG_ENABLE
 ],
 
 with, [
-AC_ARG_WITH([$2], [$3], [
+AC_ARG_WITH([$2], [AS_HELP_STRING([--]m4_if($3, -, without, with)[-$2]m4_if($3, -, , $3), [$4])], [
   case [$]withval in
     yes)
-      m4_default([$4], :)
+      m4_default([$5], :)
       ;;
     no)
-      m4_default([$5], :)
+      m4_default([$6], :)
       ;;
     *)
-      $6
+      $7
       ;;
   esac
 ],
-[$7])[]dnl AC_ARG_WITH
+[$8])[]dnl AC_ARG_WITH
 ],
 
 [m4_fatal([first argument of $0 must be 'enable' or 'with', not '$1'])]
@@ -86,9 +91,9 @@ AC_DEFUN([PGAC_ARG_CHECK],
   AC_MSG_WARN([option ignored: --$pgac_txt])
 done])# PGAC_ARG_CHECK
 
-# PGAC_ARG_BOOL(TYPE, NAME, DEFAULT, HELP-STRING, 
+# PGAC_ARG_BOOL(TYPE, NAME, DEFAULT, HELP-STRING-RHS,
 #               [ACTION-IF-YES], [ACTION-IF-NO])
-# -----------------------------------------------
+# ---------------------------------------------------
 # Accept a boolean option, that is, one that only takes yes or no.
 # ("no" is equivalent to "disable" or "without"). DEFAULT is what
 # should be done if the option is omitted; it should be "yes" or "no".
@@ -96,7 +101,13 @@ done])# PGAC_ARG_CHECK
 # execute.)
 
 AC_DEFUN([PGAC_ARG_BOOL],
-[PGAC_ARG([$1], [$2], [$4], [$5], [$6], 
+[dnl The following hack is necessary because in a few instances this
+dnl macro is called twice for the same option with different default
+dnl values.  But we only want it to appear once in the help.  We achieve
+dnl that by making the help string look the same, which is why we need to
+dnl save the default that was passed in previously.
+m4_define([_pgac_helpdefault], m4_ifdef([pgac_defined_$1_$2_bool], [m4_defn([pgac_defined_$1_$2_bool])], [$3]))dnl
+PGAC_ARG([$1], [$2], [m4_if(_pgac_helpdefault, yes, -)], [$4], [$5], [$6], 
           [AC_MSG_ERROR([no argument expected for --$1-$2 option])],
           [m4_case([$3],
                    yes, [pgac_arg_to_variable([$1], [$2])=yes
@@ -104,25 +115,28 @@ $5],
                    no,  [pgac_arg_to_variable([$1], [$2])=no
 $6],
                    [m4_fatal([third argument of $0 must be 'yes' or 'no', not '$3'])])])[]dnl
+m4_define([pgac_defined_$1_$2_bool], [$3])dnl
 ])# PGAC_ARG_BOOL
 
 
-# PGAC_ARG_REQ(TYPE, NAME, HELP-STRING, [ACTION-IF-GIVEN], [ACTION-IF-NOT-GIVEN])
-# -------------------------------------------------------------------------------
+# PGAC_ARG_REQ(TYPE, NAME, HELP-ARGNAME, HELP-STRING-RHS,
+#              [ACTION-IF-GIVEN], [ACTION-IF-NOT-GIVEN])
+# -------------------------------------------------------
 # This option will require an argument; "yes" or "no" will not be
-# accepted.
+# accepted.  HELP-ARGNAME is a name for the argument for the help output.
 
 AC_DEFUN([PGAC_ARG_REQ],
-[PGAC_ARG([$1], [$2], [$3],
+[PGAC_ARG([$1], [$2], [=$3], [$4],
           [AC_MSG_ERROR([argument required for --$1-$2 option])],
           [AC_MSG_ERROR([argument required for --$1-$2 option])],
-          [$4],
-          [$5])])# PGAC_ARG_REQ
+          [$5],
+          [$6])])# PGAC_ARG_REQ
 
 
-# PGAC_ARG_OPTARG(TYPE, NAME, HELP-STRING, [DEFAULT-ACTION], [ARG-ACTION]
+# PGAC_ARG_OPTARG(TYPE, NAME, HELP-ARGNAME, HELP-STRING-RHS,
+#                 [DEFAULT-ACTION], [ARG-ACTION],
 #                 [ACTION-ENABLED], [ACTION-DISABLED])
-# -----------------------------------------------------------------------
+# ----------------------------------------------------------
 # This will create an option that behaves as follows: If omitted, or
 # called with "no", then set the enable_variable to "no" and do
 # nothing else. If called with "yes", then execute DEFAULT-ACTION. If
@@ -134,18 +148,18 @@ AC_DEFUN([PGAC_ARG_REQ],
 # additional piece of information.
 
 AC_DEFUN([PGAC_ARG_OPTARG],
-[PGAC_ARG([$1], [$2], [$3], [$4], [],
+[PGAC_ARG([$1], [$2], [@<:@=$3@:>@], [$4], [$5], [],
           [pgac_arg_to_variable([$1], [$2])=yes
-$5],
+$6],
           [pgac_arg_to_variable([$1], [$2])=no])
 dnl Add this code only if there's a ACTION-ENABLED or ACTION-DISABLED.
-m4_ifval([$6[]$7],
+m4_ifval([$7[]$8],
 [
 if test "[$]pgac_arg_to_variable([$1], [$2])" = yes; then
-  m4_default([$6], :)
-m4_ifval([$7],
+  m4_default([$7], :)
+m4_ifval([$8],
 [else
-  $7
+  $8
 ])[]dnl
 fi
 ])[]dnl

configure

@@ -1353,10 +1353,13 @@ if test -n "$ac_init_help"; then
 Optional Features:
   --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
   --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]
-  --disable-integer-datetimes  disable 64-bit integer date/time support
-  --enable-nls[=LANGUAGES]  enable Native Language Support
+  --disable-integer-datetimes
+                          disable 64-bit integer date/time support
+  --enable-nls[=LANGUAGES]
+                          enable Native Language Support
   --disable-shared        do not build shared libraries
-  --disable-rpath         do not embed shared library search path in executables
+  --disable-rpath         do not embed shared library search path in
+                          executables
   --disable-spinlocks     do not use spinlocks
   --enable-debug          build with debugging symbols (-g)
   --enable-profiling      build with profiling enabled
@@ -1365,7 +1368,8 @@ Optional Features:
   --enable-depend         turn on automatic dependency tracking
   --enable-cassert        enable assertion checks (for debugging)
   --enable-thread-safety  make client libraries thread-safe
-  --enable-thread-safety-force  force thread-safety despite thread test failure
+  --enable-thread-safety-force
+                          force thread-safety despite thread test failure
   --disable-float4-byval  disable float4 passed by value
   --disable-float8-byval  disable float8 passed by value
   --disable-largefile     omit support for large files
@@ -1373,32 +1377,40 @@ Optional Features:
 Optional Packages:
   --with-PACKAGE[=ARG]    use PACKAGE [ARG=yes]
   --without-PACKAGE       do not use PACKAGE (same as --with-PACKAGE=no)
-
+  --with-template=NAME    override operating system template
   --with-includes=DIRS    look for additional header files in DIRS
   --with-libraries=DIRS   look for additional libraries in DIRS
   --with-libs=DIRS        alternative spelling of --with-libraries
   --with-pgport=PORTNUM   set default port number [5432]
-  --with-blocksize=BLOCKSIZE  set table block size in kB [8]
+  --with-blocksize=BLOCKSIZE
+                          set table block size in kB [8]
   --with-segsize=SEGSIZE  set table segment size in GB [1]
-  --with-wal-blocksize=BLOCKSIZE  set WAL block size in kB [8]
-  --with-wal-segsize=SEGSIZE  set WAL segment size in MB [16]
+  --with-wal-blocksize=BLOCKSIZE
+                          set WAL block size in kB [8]
+  --with-wal-segsize=SEGSIZE
+                          set WAL segment size in MB [16]
+  --with-CC=CMD           set compiler (deprecated)
   --with-tcl              build Tcl modules (PL/Tcl)
   --with-tclconfig=DIR    tclConfig.sh is in DIR
   --with-perl             build Perl modules (PL/Perl)
   --with-python           build Python modules (PL/Python)
   --with-gssapi           build with GSSAPI support
   --with-krb5             build with Kerberos 5 support
-  --with-krb-srvnam=NAME  default service principal name in Kerberos [postgres]
+  --with-krb-srvnam=NAME  default service principal name in Kerberos
+                          [postgres]
   --with-pam              build with PAM support
   --with-ldap             build with LDAP support
   --with-bonjour          build with Bonjour support
   --with-openssl          build with OpenSSL support
   --without-readline      do not use GNU Readline nor BSD Libedit for editing
-  --with-libedit-preferred  prefer BSD Libedit over GNU Readline
-  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp
+  --with-libedit-preferred
+                          prefer BSD Libedit over GNU Readline
+  --with-ossp-uuid        use OSSP UUID library when building
+                          contrib/uuid-ossp
   --with-libxml           build with XML support
   --with-libxslt          use XSLT support when building contrib/xml2
-  --with-system-tzdata=DIR  use system time zone data in DIR
+  --with-system-tzdata=DIR
+                          use system time zone data in DIR
   --without-zlib          do not use Zlib
   --with-gnu-ld           assume the C compiler uses GNU ld [default=no]
 

configure.in

 dnl Process this file with autoconf to produce a configure script.
-dnl $PostgreSQL: pgsql/configure.in,v 1.567 2008/09/05 18:54:58 petere Exp $
+dnl $PostgreSQL: pgsql/configure.in,v 1.568 2008/10/29 09:27:24 petere Exp $
 dnl
 dnl Developers, please strive to achieve this order:
 dnl
@@ -36,7 +36,7 @@ AC_CANONICAL_HOST
 template=
 AC_MSG_CHECKING([which template to use])
 
-PGAC_ARG_REQ(with, template, [],
+PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
 [
   case $withval in
     list)   echo; ls "$srcdir/src/template"; exit;;
@@ -114,16 +114,16 @@ tas_file=dummy.s
 #
 # Add non-standard directories to the include path
 #
-PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
+PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 
 
 #
 # Add non-standard directories to the library search path
 #
-PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
+PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
              [LIBRARY_DIRS=$withval])
 
-PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
+PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
              [LIBRARY_DIRS=$withval])
 
 
@@ -131,7 +131,7 @@ PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of
 # 64-bit integer date/time storage: enabled by default.
 #
 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
-PGAC_ARG_BOOL(enable, integer-datetimes, yes, [  --disable-integer-datetimes  disable 64-bit integer date/time support],
+PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 AC_MSG_RESULT([$enable_integer_datetimes])
@@ -142,7 +142,7 @@ AC_MSG_RESULT([$enable_integer_datetimes])
 #
 AC_MSG_CHECKING([whether NLS is wanted])
 PGAC_ARG_OPTARG(enable, nls,
-                [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
+                [LANGUAGES], [enable Native Language Support],
                 [],
                 [WANTED_LANGUAGES=$enableval],
                 [AC_DEFINE(ENABLE_NLS, 1,
@@ -155,7 +155,7 @@ AC_SUBST(WANTED_LANGUAGES)
 # Default port number (--with-pgport), default 5432
 #
 AC_MSG_CHECKING([for default port number])
-PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   set default port number [[5432]]],
+PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
              [default_port=$withval],
              [default_port=5432])
 AC_MSG_RESULT([$default_port])
@@ -173,41 +173,41 @@ AC_SUBST(default_port)
 # Option to disable shared libraries
 #
 PGAC_ARG_BOOL(enable, shared, yes,
-              [  --disable-shared        do not build shared libraries])
+              [do not build shared libraries])
 AC_SUBST(enable_shared)
 
 #
 # '-rpath'-like feature can be disabled
 #
 PGAC_ARG_BOOL(enable, rpath, yes,
-              [  --disable-rpath         do not embed shared library search path in executables])
+              [do not embed shared library search path in executables])
 AC_SUBST(enable_rpath)
 
 #
 # Spinlocks
 #
 PGAC_ARG_BOOL(enable, spinlocks, yes,
-              [  --disable-spinlocks     do not use spinlocks])
+              [do not use spinlocks])
 
 #
 # --enable-debug adds -g to compiler flags
 #
 PGAC_ARG_BOOL(enable, debug, no,
-              [  --enable-debug          build with debugging symbols (-g)])
+              [build with debugging symbols (-g)])
 AC_SUBST(enable_debug)
 
 #
 # --enable-profiling enables gcc profiling
 #
 PGAC_ARG_BOOL(enable, profiling, no,
-              [  --enable-profiling      build with profiling enabled ])
+              [build with profiling enabled ])
 AC_SUBST(enable_profiling)
 
 #
 # --enable-coverage enables generation of code coverage metrics with gcov
 #
 PGAC_ARG_BOOL(enable, coverage, no,
-              [  --enable-coverage       build with coverage testing instrumentation],
+              [build with coverage testing instrumentation],
 [AC_CHECK_PROGS(GCOV, gcov)
 if test -z "$GCOV"; then
   AC_MSG_ERROR([gcov not found])
@@ -226,7 +226,7 @@ AC_SUBST(enable_coverage)
 # DTrace
 #
 PGAC_ARG_BOOL(enable, dtrace, no,
-              [  --enable-dtrace         build with DTrace support],
+              [build with DTrace support],
 [AC_DEFINE([ENABLE_DTRACE], 1, 
            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 AC_CHECK_PROGS(DTRACE, dtrace)
@@ -240,7 +240,7 @@ AC_SUBST(enable_dtrace)
 # Block size
 #
 AC_MSG_CHECKING([for block size])
-PGAC_ARG_REQ(with, blocksize, [  --with-blocksize=BLOCKSIZE  set table block size in kB [[8]]],
+PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
              [blocksize=$withval],
              [blocksize=8])
 case ${blocksize} in
@@ -272,7 +272,7 @@ AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 # Relation segment size
 #
 AC_MSG_CHECKING([for segment size])
-PGAC_ARG_REQ(with, segsize, [  --with-segsize=SEGSIZE  set table segment size in GB [[1]]],
+PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
              [segsize=$withval],
              [segsize=1])
 # this expression is set up to avoid unnecessary integer overflow
@@ -304,7 +304,7 @@ AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 # WAL block size
 #
 AC_MSG_CHECKING([for WAL block size])
-PGAC_ARG_REQ(with, wal-blocksize, [  --with-wal-blocksize=BLOCKSIZE  set WAL block size in kB [[8]]],
+PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
              [wal_blocksize=$withval],
              [wal_blocksize=8])
 case ${wal_blocksize} in
@@ -332,7 +332,7 @@ AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 # WAL segment size
 #
 AC_MSG_CHECKING([for WAL segment size])
-PGAC_ARG_REQ(with, wal-segsize, [  --with-wal-segsize=SEGSIZE  set WAL segment size in MB [[16]]],
+PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
              [wal_segsize=$withval],
              [wal_segsize=16])
 case ${wal_segsize} in
@@ -362,7 +362,7 @@ AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 # For historical reasons you can also use --with-CC to specify the C compiler
 # to use, although the standard way to do this is to set the CC environment
 # variable.
-PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
+PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 
 case $template in
   aix) pgac_cc_list="gcc xlc";;
@@ -507,7 +507,7 @@ AC_SUBST(TAS)
 #
 # Automatic dependency tracking
 #
-PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
+PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
               [autodepend=yes])
 AC_SUBST(autodepend)
 
@@ -515,7 +515,7 @@ AC_SUBST(autodepend)
 #
 # Enable assert checks
 #
-PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
+PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 
@@ -557,13 +557,13 @@ IFS=$ac_save_IFS
 #
 AC_MSG_CHECKING([allow thread-safe client libraries])
 if test "$PORTNAME" != "win32"; then
-PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
+PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 else
 # Win32 should always use threads
-PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
+PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 fi
 
-PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
+PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 if test "$enable_thread_safety" = yes -o \
         "$enable_thread_safety_force" = yes; then
   enable_thread_safety="yes"	# for 'force'
@@ -577,20 +577,20 @@ AC_SUBST(enable_thread_safety)
 # Optionally build Tcl modules (PL/Tcl)
 #
 AC_MSG_CHECKING([whether to build with Tcl])
-PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
+PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 AC_MSG_RESULT([$with_tcl])
 AC_SUBST([with_tcl])
 
 # We see if the path to the Tcl/Tk configuration scripts is specified.
 # This will override the use of tclsh to find the paths to search.
 
-PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
+PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 
 #
 # Optionally build Perl modules (PL/Perl)
 #
 AC_MSG_CHECKING([whether to build Perl modules])
-PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
+PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 AC_MSG_RESULT([$with_perl])
 AC_SUBST(with_perl)
 
@@ -598,7 +598,7 @@ AC_SUBST(with_perl)
 # Optionally build Python modules (PL/Python)
 #
 AC_MSG_CHECKING([whether to build Python modules])
-PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
+PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 AC_MSG_RESULT([$with_python])
 AC_SUBST(with_python)
 
@@ -606,7 +606,7 @@ AC_SUBST(with_python)
 # GSSAPI
 #
 AC_MSG_CHECKING([whether to build with GSSAPI support])
-PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
+PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 [
   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
@@ -618,7 +618,7 @@ AC_SUBST(with_gssapi)
 # Kerberos 5
 #
 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
-PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
+PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 [
   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
@@ -634,7 +634,7 @@ AC_SUBST(krb_srvtab)
 # Kerberos configuration parameters
 #
 PGAC_ARG_REQ(with, krb-srvnam,
-             [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
+             [NAME], [default service principal name in Kerberos [postgres]],
              [],
              [with_krb_srvnam="postgres"])
 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
@@ -646,7 +646,7 @@ AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 #
 AC_MSG_CHECKING([whether to build with PAM support])
 PGAC_ARG_BOOL(with, pam, no,
-              [  --with-pam              build with PAM support],
+              [build with PAM support],
               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 AC_MSG_RESULT([$with_pam])
 AC_SUBST(with_pam)
@@ -657,7 +657,7 @@ AC_SUBST(with_pam)
 #
 AC_MSG_CHECKING([whether to build with LDAP support])
 PGAC_ARG_BOOL(with, ldap, no,
-              [  --with-ldap             build with LDAP support],
+              [build with LDAP support],
               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 AC_MSG_RESULT([$with_ldap])
 AC_SUBST(with_ldap)
@@ -668,7 +668,7 @@ AC_SUBST(with_ldap)
 #
 AC_MSG_CHECKING([whether to build with Bonjour support])
 PGAC_ARG_BOOL(with, bonjour, no,
-              [  --with-bonjour          build with Bonjour support],
+              [build with Bonjour support],
               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 AC_MSG_RESULT([$with_bonjour])
 AC_SUBST(with_bonjour)
@@ -678,7 +678,7 @@ AC_SUBST(with_bonjour)
 # OpenSSL
 #
 AC_MSG_CHECKING([whether to build with OpenSSL support])
-PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
+PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 AC_MSG_RESULT([$with_openssl])
 AC_SUBST(with_openssl)
@@ -688,7 +688,7 @@ AC_SUBST(with_openssl)
 # Readline
 #
 PGAC_ARG_BOOL(with, readline, yes,
-              [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
+              [do not use GNU Readline nor BSD Libedit for editing])
 # readline on MinGW has problems with backslashes in psql and other bugs.
 # This is particularly a problem with non-US code pages.
 # Therefore disable its use until we understand the cause. 2004-07-20
@@ -704,20 +704,20 @@ fi
 # Prefer libedit
 #
 PGAC_ARG_BOOL(with, libedit-preferred, no,
-              [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
+              [prefer BSD Libedit over GNU Readline])
 
 
 #
 # OSSP UUID library
 #
-PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp])
+PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 AC_SUBST(with_ossp_uuid)
 
 
 #
 # XML
 #
-PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
+PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 
 if test "$with_libxml" = yes ; then
@@ -741,7 +741,7 @@ AC_SUBST(with_libxml)
 #
 # XSLT
 #
-PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          use XSLT support when building contrib/xml2],
+PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 
 
@@ -751,14 +751,14 @@ AC_SUBST(with_libxslt)
 # tzdata
 #
 PGAC_ARG_REQ(with, system-tzdata,
-             [  --with-system-tzdata=DIR  use system time zone data in DIR])
+             [DIR], [use system time zone data in DIR])
 AC_SUBST(with_system_tzdata)
 
 #
 # Zlib
 #
 PGAC_ARG_BOOL(with, zlib, yes,
-              [  --without-zlib          do not use Zlib])
+              [do not use Zlib])
 AC_SUBST(with_zlib)
 
 #
@@ -1509,7 +1509,7 @@ AC_CHECK_SIZEOF([size_t])
 
 # Decide whether float4 is passed by value: user-selectable, enabled by default
 AC_MSG_CHECKING([whether to build with float4 passed by value])   
-PGAC_ARG_BOOL(enable, float4-byval, yes, [  --disable-float4-byval  disable float4 passed by value],
+PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
                float4passbyval=true],
@@ -1521,11 +1521,11 @@ AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are pas
 # Note: this setting also controls int8 and related types such as timestamp.
 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
 # If not, trying to select it is an error.
-AC_MSG_CHECKING([whether to build with float8 passed by value])   
+AC_MSG_CHECKING([whether to build with float8 passed by value])
 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
-  PGAC_ARG_BOOL(enable, float8-byval, yes, [  --disable-float8-byval  disable float8 passed by value])
+  PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
 else
-  PGAC_ARG_BOOL(enable, float8-byval, no, [  --disable-float8-byval  disable float8 passed by value])
+  PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
   if test "$enable_float8_byval" = yes ; then
     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
   fi